home *** CD-ROM | disk | FTP | other *** search
/ Commodore Disc 2 / Commodore_Disc_02_19xx_-_de.d64 / kalorientab. 64 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  15KB  |  469 lines
  1. 10 rem kalorientabelle ==========64
  2. 20 rem (p) 87 commodore welt team =
  3. 30 rem ============================
  4. 40 rem original by percy          =
  5. 50 rem & egon kwapil              =
  6. 60 rem                            =
  7. 70 rem version 2.0  40z/ascii     =
  8. 80 rem c-64 + 1530/1541/1570/1571 =
  9. 90 rem ============================
  10. 100 x=42:gosub4190:printcl$:gosub220
  11. 110 poke53280,0:poke53281,0:poke53272,23
  12. 120 dimsp$(500),s$(500),d$(100)
  13. 130 rem ***************************
  14. 140 rem *************** umrandung *
  15. 150 rem ***************************
  16. 160 printtab(1);rd$rn$cd$kl$
  17. 170 printchr$(30);tab(14);cd$cd$cd$cd$"([195]) by [208]ercy"
  18. 180 printtab(14);cd$"[197]gon  [203]wapil"
  19. 190 printtab(13);cd$"[195][207][205][205][207][196][207][210][197][160][215][197][204][212]"
  20. 200 fori=1to3000:next
  21. 210 goto340
  22. 220 forn=1024to1063:poken,x:next
  23. 230 forn=55296to55335:poken,6:next
  24. 240 forn=1063to2023step40:poken,x:next
  25. 250 forn=55335to56295step40:poken,6:next
  26. 260 forn=1984to2023:poken,x:next
  27. 270 forn=56256to56295:poken,6:next
  28. 280 forn=1984to1024step-40:poken,x:next
  29. 290 forn=56256to55296step-40:poken,6:next
  30. 300 fori=1to150:next:return
  31. 310 rem ***************************
  32. 320 rem ************ beschreibung *
  33. 330 rem ***************************
  34. 340 printks$
  35. 350 print" [205]it diesem [208]rogramm koennen [211]ie den"
  36. 360 print" [203]aloriengehalt und den [197]iweiss-"
  37. 370 print" gehalt den [198]ettgehalt und den"
  38. 380 print" [203]ohlenhydrategehalt verschiedener"
  39. 390 print" [211]peisen ermitteln."
  40. 400 print" [193]usserdem koennen sie nach [197]ingabe der"
  41. 410 print" [204]ebensmittlelmenge, die [211]ie zu [211]ich"
  42. 420 print" genommen haben, [201]hre persoenliche"
  43. 430 print" [193]uswertung abrufen."
  44. 440 print" [196]adurch wird es [201]hnen moeglich, [201]hre"
  45. 450 print" [197]rnaehrung in der [218]ukunft den"
  46. 460 print" benoetigten [205]engen anzupassen.":print:print
  47. 470 printwt$;we$:gosub4400
  48. 480 poke198,0:wait198,1
  49. 490 ifpeek(203)=14then1830
  50. 500 printks$
  51. 510 print"  [202]eder zweite [194]undesbuerger, egal ob"
  52. 520 print"  [215]eiblich oder [205]aennlich, moechte"
  53. 530 print"  gern ein paaar [203]ilo leichter sein,"
  54. 540 print"  aber trotzdem auf [199]enuss, [198]reude und"
  55. 550 print"  [211]pass beim [197]ssen nicht verzichten"
  56. 560 print"  [196]iese guten [214]orsaetze scheitern"
  57. 570 print"  jedoch meisstens am [206]icht-[194]escheid-"
  58. 580 print"  [215]issen ueber den [197]nergie- und [206]aehr-"
  59. 590 print"  stoffgehalt der [206]ahrungsmittel."
  60. 600 print"  [196]er [213]mgang mit diesem [208]rogramm soll"
  61. 610 print"  [201]hnen nun dabei helfen."
  62. 620 print"  [196]ie [215]erte sind portionsweise zu"
  63. 630 print"  verstehen, das heisst pro [208]ortion,"
  64. 640 print"  [211]tueck, [211]cheibe, [212]asse, [199]las,"
  65. 650 print"  [197]ssloeffel oder [203]affeeloeffel.":print
  66. 660 printwt$;we$:gosub4400
  67. 670 poke198,0:wait198,1
  68. 680 ifpeek(203)=14 then1830
  69. 690 printks$
  70. 700 printye$" [215]as man ueber [203]alorien wissen sollte !"
  71. 710 printrd$" [203]ilokalorien ([203]cal) stammt von dem"
  72. 720 print" lateinischen [215]ort 'calor' und bedeutet"
  73. 730 print" [215]aerme. [197]ine [203]ilokalorie ([203]cal)"
  74. 740 print" ist diejenige [215]aermemenge, die"
  75. 750 print" notwendig ist um 1 [203]g [215]asser"
  76. 760 print" von 14.5 [195] auf 15.5 [195] zu erwaermen.":print:print
  77. 770 printwt$;we$
  78. 780 poke198,0:wait198,1
  79. 790 ifpeek(203)=14then1830
  80. 800 poke198,0:goto1830
  81. 810 rem ***************************
  82. 820 rem ************ dateneingabe *
  83. 830 rem ***************************
  84. 840 printks$
  85. 850 gosub4400:printcy$"[201]hr [193]lter"
  86. 860 x=4:y=20:gosub4490:l=2:z=1:r=1:gosub4500
  87. 870 al=val(e$):print:gosub4400
  88. 880 print"[201]hr [199]ewicht in [203]g.":x=6:y=20:gosub4490:l=3:z=1:r=2:gosub4500
  89. 890 kg=val(e$):ifal<10then1040
  90. 900 rem ***************************
  91. 910 rem ********* wertzuweisungen *
  92. 920 rem ***************************
  93. 930 ifkg<55thenkb=1600:goto1070
  94. 940 ifkg<60thenkb=1800:goto1070
  95. 950 ifkg<65thenkb=1950:goto1070
  96. 960 ifkg<70thenkb=2100:goto1070
  97. 970 ifkg<75thenkb=2250:goto1070
  98. 980 ifkg<80thenkb=2400:goto1070
  99. 990 ifkg<85thenkb=2600:goto1070
  100. 1000 ifkg<90thenkb=2750:goto1070
  101. 1010 ifkg<95thenkb=2900:goto1070
  102. 1020 ifkg<100thenkb=2900:goto1070
  103. 1030 ifkg>100thenkb=2500:goto1070
  104. 1040 ifal<4thenkb=kg*80:goto1070
  105. 1050 ifal<7thenkb=kg*75:goto1070
  106. 1060 ifal<10thenkb=kg*65
  107. 1070 eb=int(kg/0.9):hb=kg*5:print:fb=kg
  108. 1080 rem **************************
  109. 1090 rem ********* bedarfsausgabe *
  110. 1100 rem **************************
  111. 1110 printcd$cd$cd$cd$rd$"[201]hr [203]alorienbedarf   =";kb;" [212]ag"cd$
  112. 1120 print"[201]hr [198]ettbedarf       =";fb;"[199]ramm/[212]ag"cd$
  113. 1130 print"[201]hr [197]iweissbedarf    =";eb;"[199]ramm/[212]ag"cd$
  114. 1140 print"[201]hr [203]ohl. [200]ydr. [194]ed. =";hb;"[199]ramm/[212]ag"cd$
  115. 1150 printcd$cd$cd$cd$wt$
  116. 1160 poke198,0:wait198,1:gosub4400:poke198,0
  117. 1170 goto2370
  118. 1180 rem **************************
  119. 1190 rem ******** directory lesen *
  120. 1200 rem **************************
  121. 1210 fori=0to100:d$(i)="":next
  122. 1220 printf1$s1$"[203]alorien-[201]naltsverzeichnis      "cd$
  123. 1230 co=0
  124. 1240 printcy$;
  125. 1250 open1,8,0,"$0"
  126. 1260 get#1,a$,b$
  127. 1270 get#1,a$,b$
  128. 1280 get#1,a$,b$
  129. 1290 c=0
  130. 1300 ifa$<>""thenc=asc(a$)
  131. 1310 ifb$<>""thenc=c+asc(b$)*256
  132. 1320 get#1,b$:ifst<>0then1400
  133. 1330 ifb$<>chr$(47)then1320
  134. 1340 get#1,b$:ifb$<>chr$(34)thenprinttab(4);b$;:d$(co)=d$(co)+b$:goto1340
  135. 1350 get#1,b$:ifb$=chr$(32)then1350
  136. 1360 printtab(19);:c$=""
  137. 1370 c$=c$+b$:get#1,b$:ifb$<>""then1370
  138. 1380 printrd$left$(c$,3)
  139. 1390 ifst=0thenprintcy$;:co=co+1:goto1270
  140. 1400 print:close1
  141. 1410 close1:goto1420
  142. 1420 printwt$;we$
  143. 1430 poke198,0:wait198,1
  144. 1440 ifpeek(203)=14then4600
  145. 1450 poke198,0:goto1830
  146. 1460 ifq>1000thenfora=1to35:printfu$:next:goto1830
  147. 1470 rem **************************
  148. 1480 rem *********** dateneingabe *
  149. 1490 rem **************************
  150. 1500 printf1$s1$"[203]aloriendateneingabe"s2$cd$cd$
  151. 1510 printcd$cy$"[206]ame       =>"cd$
  152. 1520 gosub4400:x=4:y=17:gosub4490:l=15:r=1:z=0:gosub4500
  153. 1530 sp$=e$
  154. 1540 printcd$cy$"kalorien   =>"cd$
  155. 1550 gosub4400:x=6:y=17:gosub4490:l=3:r=1:z=1:gosub4500
  156. 1560 ka$=e$
  157. 1570 printcd$cy$"[197]iweiss    =>"cd$
  158. 1580 gosub4400:x=8:y=17:gosub4490:l=3:r=1:z=1:gosub4500
  159. 1590 ew$=e$
  160. 1600 printcd$cy$"[198]ett       =>"cd$
  161. 1610 gosub4400:x=10:y=17:gosub4490:l=3:r=1:z=1:gosub4500
  162. 1620 fe$=e$
  163. 1630 printcd$cy$"[203]ohlehydrate  =>"cd$
  164. 1640 gosub4400:x=12:y=17:gosub4490:l=3:r=1:z=1:gosub4500
  165. 1650 kh$=e$
  166. 1660 gosub2900
  167. 1670 te$=left$(sp$+"             ",15)+right$("      "+ka$,4)
  168. 1680 te$=te$+" "+right$("   "+ew$,3)
  169. 1690 te$=te$+" "+right$("   "+fe$,3)
  170. 1700 te$=te$+" "+right$("   "+kh$,3)
  171. 1710 te$=te$+" "+right$("  "+ar$,2)
  172. 1720 printcd$ye$rn$" [197]ingabe korrekt (j/n) "
  173. 1730 x=15:y=24:gosub4490:z=0:l=1:r=0:gosub4500
  174. 1740 a$=e$:ifa$="n"then1490
  175. 1750 ifa$="j"thenq=q+1:sp$(q)=te$:te$="":goto1770
  176. 1760 printcu$cu$cu$:goto1720
  177. 1770 printcu$cu$:printwt$we$:poke198,0:wait198,1
  178. 1780 ifpeek(203)=14then1830
  179. 1790 poke198,0:goto1460
  180. 1800 rem **************************
  181. 1810 rem ************* hauptmenue *
  182. 1820 rem **************************
  183. 1830 printf1$s1$"[203]alorientabelle"s2$cd$cd$
  184. 1840 printcd$cd$cy$"(1)      [201]nhaltsverzeichnis"cd$
  185. 1850 print"(2)         [203]alorien laden"cd$
  186. 1860 print"(3)         [203]alorien speichern"cd$
  187. 1870 print"(4)         [203]alorien eingeben"cd$
  188. 1880 print"(5)         [203]alorien listen"cd$
  189. 1890 print"(6)         [208]rogramm [197]nde"cd$cd$
  190. 1900 printgr$rn$"[201]hre [197]ingabe [194]itte"
  191. 1910 gosub4400:x=18:y=21:gosub4490:l=1:r=1:z=1:gosub4500
  192. 1920 ee=val(e$):if(ee<1)or(ee>6)then1830
  193. 1930 onval(e$)goto1220,2060,1940,1490,2250,4600
  194. 1940 rem **************************
  195. 1950 rem ***** kalorien speichern *
  196. 1960 rem **************************
  197. 1970 ifq<1then1830
  198. 1980 printf1$cd$s1$"[203]alorien [211]peichern"s2$cd$cd$
  199. 1990 printcd$cy$"[193]bspeichern unter"
  200. 2000 gosub4400:x=5:y=19:gosub4490:l=10:r=0:z=0:gosub4500
  201. 2010 ab$="@:kalo/"+e$+",s,w"
  202. 2020 open1,8,1,ab$
  203. 2030 print#1,str$(q);chr$(13);:printye$cd$cd$"[196]atenmenge = ";q
  204. 2040 forw=1toq:print#1,sp$(w);chr$(13);:next
  205. 2050 close1:goto1830
  206. 2060 rem **************************
  207. 2070 rem ********* kalorien laden *
  208. 2080 rem **************************
  209. 2090 printf1$cd$s1$"[203]alorien laden"s2$cd$cd$
  210. 2100 fori=0toco:printtab(4);d$(i):next
  211. 2110 clr:dimsp$(500),s$(500),d$(100):gosub4190
  212. 2120 printcd$cy$"[199]espeichert unter"cd$cd$
  213. 2130 gosub4400:x=peek(214)-3 :y=19:gosub4490:l=10:r=0:z=0:gosub4500
  214. 2140 se$=e$
  215. 2150 ab$="kalo/"+se$+",s,r"
  216. 2160 open1,8,0,ab$
  217. 2170 input#1,x$:q=val(x$):printye$cd$cd$"[196]atenmenge =";q
  218. 2180 ifq<1thenprintkd$:forkd=1to1500:next:goto2210
  219. 2190 forw=1toq:input#1,sp$(w):next
  220. 2200 ifb=1thenclose1:return
  221. 2210 close1:goto4010
  222. 2220 rem **************************
  223. 2230 rem *********** untermenue 1 *
  224. 2240 rem **************************
  225. 2250 printcl$rd$rn$"[203]alorientabelle"cd$cd$
  226. 2260 printcd$cd$cy$"(1)   [203]alorien [193]uswerten"cd$
  227. 2270 print"(2)   [203]alorien [211]ortieren "cd$
  228. 2280 print"(3)   [203]alorien [193]uflisten"cd$
  229. 2290 print"(4)   [197]nde"cd$
  230. 2300 printye$rn$"[201]hre [197]ingabe [194]itte"
  231. 2310 gosub4400:x=13:y=21:gosub4490:l=1:r=1:z=1:gosub4500
  232. 2320 ee=val(e$):if(ee<1)or(ee>4)then2250
  233. 2330 onval(e$)goto810,3190,4010,1830
  234. 2340 rem **************************
  235. 2350 rem ***** auswertungseingabe *
  236. 2360 rem **************************
  237. 2370 ifse$<>"tabelle"thense$="tabelle":b=1:gosub2150
  238. 2380 b=2:gosub2900:au=0:zk=1
  239. 2390 printcl$:ifar$="99"thengoto2680
  240. 2400 forau=1tow
  241. 2410 ifar$=mid$(sp$(au),33,1)then2430
  242. 2420 goto2460
  243. 2430 ifzk=1thenprintye$;au;tab(5);cy$;mid$(sp$(au),1,15);:zk=0:goto2460
  244. 2440 ifar$<>mid$(sp$(au),33,1)thenzk=0:goto2460
  245. 2450 ifzk=0thenprinttab(20);ye$;au;cy$;tab(25);mid$(sp$(au),1,14):zk=1
  246. 2460 next
  247. 2470 poke211,0
  248. 2480 printrn$ye$" [194]itte geben [211]ie die [206]ummer vor der    "
  249. 2490 printrn$" [194]ezeichung was [211]ie gegessen oder      "
  250. 2500 printrn$" getrunken haben ein .                 "
  251. 2510 gosub4400
  252. 2520 printcy$
  253. 2530 input"[206]ummer ";nr:printcu$;tab(20);:input"[193]nzahl ";az
  254. 2540 ka$=mid$(sp$(nr),17,3):ka=val(ka$)
  255. 2550 ei$=mid$(sp$(nr),21,3):ei=val(ei$)
  256. 2560 fe$=mid$(sp$(nr),25,3):fe=val(fe$)
  257. 2570 ko$=mid$(sp$(nr),29,3):ko=val(ko$)
  258. 2580 kv=kv+ka*az:ev=ev+ei*az
  259. 2590 fv=fv+fe*az:hv=hv+ko*az
  260. 2600 gosub4400:printye$cu$
  261. 2610 input"[215]eitere [193]rten = 1, [193]nderes [199]ebiet = 2";xx
  262. 2620 ifxx=2thengoto2380
  263. 2630 printcu$cu$"                                       "
  264. 2640 printcu$cu$;spc(39);cu$:goto2510
  265. 2650 rem **************************
  266. 2660 rem ***** auswertungsausgabe *
  267. 2670 rem **************************
  268. 2680 printf1$kl$cd$ye$
  269. 2690 print"[201]hr [203]alorienbedarf =";kb;"[212]ag"
  270. 2700 print"[203]alorienverbrauch  =";kv
  271. 2710 print"[196]ifferenz          =";:di=kb-kv:printdi:print
  272. 2720 print"[201]hr [198]ettbegarf     =";fb;"[199]ramm/[212]ag"
  273. 2730 print"[198]ettverbrauch      =";fv
  274. 2740 print"[196]ifferenz          =";:di=fb-fv:printdi:print
  275. 2750 print"[201]hr [203]ohl.[200]yd.[194]edarf=";hb;" [199]ramm/[212]ag"
  276. 2760 print"[203]ohl.[200]ydr.[214]erbr.   =";hv
  277. 2770 print"[196]ifferenz          =";:di=hb-hv:printdi:print
  278. 2780 print"[201]hr [197]iweissbedarf  =";eb;" [199]ramm/[212]ag"
  279. 2790 print"[197]iweissverbrauch   =";ev
  280. 2800 print"[196]ifferenz          =";:di=eb-ev:printdi:print
  281. 2810 gosub4400
  282. 2820 printrn$"[193]nfang = 1, [197]nde = 2 "
  283. 2830 x=18:y=23:gosub4490:l=1:z=1:r=1:gosub4500
  284. 2840 xx=val(e$)
  285. 2850 ifxx=2goto4370
  286. 2860 kv=0:ev=0:hv=0:fv=0:goto1830
  287. 2870 rem **************************
  288. 2880 rem ********* eingabeauswahl *
  289. 2890 rem **************************
  290. 2900 printf1$s1$"[197]ingabe [193]uswahl"s2$cd$cd$
  291. 2910 ifb=2thenprintf1$kl$cd$cd$
  292. 2920 printcy$"[199]etraenke     = 1  ";
  293. 2930 print"[194]rotarten     = 2"
  294. 2940 print"[193]ufstrich     = 3  ";
  295. 2950 print"[211]uppen        = 4"
  296. 2960 print"[198]leisch       = 5  ";
  297. 2970 print"[198]isch         = 6"
  298. 2980 print"[199]efluegel     = 7  ";
  299. 2990 print"[194]eilagen      = 8"
  300. 3000 print"[199]emuese-[207]bst  = 9  ";
  301. 3010 print"[211]aucen        = [193]"
  302. 3020 print"[197]ierspeisen   = [194]  ";
  303. 3030 print"[206]achtisch     = [195]"
  304. 3040 print"[215]urst         = [196]  ";
  305. 3050 print"[199]ebaeck       = [197]"
  306. 3060 print"[203]aese         = [198]  ";
  307. 3070 print"[203]uchen        = [199]"
  308. 3080 print"[211]uessigkeiten = [200]  ";
  309. 3090 ifb=2thenprint"[197]nde          =99"
  310. 3100 ifb=2thenprintcd$ye$"[201]hre [215]ahl [194]itte =>"cd$:goto3120
  311. 3110 printcd$cd$ye$"   [193]rt [194]itte   =>"cd$
  312. 3120 gosub4400:x=13:y=19:gosub4490:l=2:r=0:z=0:gosub4500
  313. 3130 ar$=e$:ifar$="99"then2680
  314. 3140 ifar$=""then2760
  315. 3150 return
  316. 3160 rem **************************
  317. 3170 rem *********** untermenue 2 *
  318. 3180 rem **************************
  319. 3190 printf1$s1$"[203]alorien-[211]ort"s2$cd$cd$
  320. 3200 printcd$cd$cy$"(1)     [211]ort        [193]-[218]"cd$
  321. 3210 print"(2)     [211]ort nach [203]alorien"cd$
  322. 3220 print"(3)     [211]ort nach [197]iweiss"cd$
  323. 3230 print"(4)     [211]ort nach [198]ett"cd$
  324. 3240 print"(5)     [211]ort nach [203]oh.[200]ydr."cd$
  325. 3250 print"(6)     [197]nde"cd$
  326. 3260 printye$rn$"[201]hre [197]ingabe [194]itte"
  327. 3270 gosub4400:x=17:y=21:gosub4490:l=1:r=1:z=1:gosub4500
  328. 3280 ee=val(e$):if(ee<1)or(ee>6)then3190
  329. 3290 onval(e$)goto3330,3690,3770,3820,3930,2250
  330. 3300 rem **************************
  331. 3310 rem ********* sortierroutine *
  332. 3320 rem **************************
  333. 3330 printf1$s1$"[203]alorien-[211]ort"s2$cd$
  334. 3340 forn=1to500:next
  335. 3350 l=int(q/2)+1:ifq=0thenprintkv$:forpp=1to1500:next:goto1830
  336. 3360 r=q:printho$rd$cd$cd$cd$cd$cd$"[206]r.  ";right$("     "+str$(abs(r)),3)
  337. 3370 ifl>1then3440
  338. 3380 ifr<=1then3430
  339. 3390 h$=sp$(l)
  340. 3400 sp$(l)=sp$(r)
  341. 3410 sp$(r)=h$
  342. 3420 r=r-1
  343. 3430 goto3450
  344. 3440 l=l-1
  345. 3450 j=l
  346. 3460 i=2*j
  347. 3470 h$=sp$(j)
  348. 3480 ifi>rthen3600
  349. 3490 ifi>=rthen3540
  350. 3500 ifsp$(i)>=sp$(i+1)then3540
  351. 3510 i=i+1
  352. 3520 printho$ye$cd$cd$cd$cd$cd$;
  353. 3530 print"[206]r. ";right$("   "+str$(i),3):printcd$cy$;sp$(i)
  354. 3540 ifi>rthen3600
  355. 3550 ifh$>=sp$(i)then3600
  356. 3560 sp$(j)=sp$(i)
  357. 3570 j=i
  358. 3580 i=2*j
  359. 3590 goto3490
  360. 3600 sp$(j)=h$
  361. 3610 ifr<>1then3370
  362. 3620 ifb=1thenreturn
  363. 3630 goto2250
  364. 3640 rem **************************
  365. 3650 rem ** $ aufteilen fuer sort *
  366. 3660 rem **************************
  367. 3670 rem ***** kalorienaufteilung *
  368. 3680 rem **************************
  369. 3690 b=1:e$=se$:gosub2150
  370. 3700 fort=1tow:s$(w)=mid$(sp$(t),17,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
  371. 3710 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
  372. 3720 fort=1tow:s$(w)=mid$(sp$(t),5,16)+mid$(sp$(t),1,4)
  373. 3730 sp$(t)=s$(w):next:b=0:goto2250
  374. 3740 rem **************************
  375. 3750 rem ****** eiweissaufteilung *
  376. 3760 rem **************************
  377. 3770 b=1:e$=se$:gosub2150
  378. 3780 fort=1tow:s$(w)=mid$(sp$(t),21,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
  379. 3790 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
  380. 3800 fort=1tow:s$(w)=mid$(sp$(t),4,16)+"   "+mid$(sp$(t),1,4)
  381. 3810 sp$(t)=s$(w):next:b=0:goto2250
  382. 3820 b=1:e$=se$:gosub2150
  383. 3830 rem **************************
  384. 3840 rem ********* fettaufteilung *
  385. 3850 rem **************************
  386. 3860 fort=1tow:s$(w)=mid$(sp$(t),25,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
  387. 3870 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
  388. 3880 fort=1tow:s$(w)=mid$(sp$(t),4,16)+"       "+mid$(sp$(t),1,4)
  389. 3890 sp$(t)=s$(w):next:b=0:goto2250
  390. 3900 rem **************************
  391. 3910 rem ****** hydrateaufteilung *
  392. 3920 rem **************************
  393. 3930 b=1:e$=se$:gosub2150
  394. 3940 fort=1tow:s$(w)=mid$(sp$(t),29,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
  395. 3950 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
  396. 3960 fort=1tow:s$(w)=mid$(sp$(t),5,16)+"           "+mid$(sp$(t),1,4)
  397. 3970 sp$(t)=s$(w):next:b=0:goto2250
  398. 3980 rem **************************
  399. 3990 rem ************* auflistung *
  400. 4000 rem **************************
  401. 4010 printf1$s1$"[193]uflistung"s2$s2$
  402. 4020 zz=0
  403. 4030 printye$"    [211]peise           [203]. [197]i. [198]t. [203]h. [193]rt     "
  404. 4040 ifq=0thenprintkv$:forkv=1to1500:next:goto1830
  405. 4050 forl=1toq:ifl+x1>1000thenx1=0:goto1830
  406. 4060 printro$;right$("   "+str$(l+x1),3);" ";:zz=zz+1
  407. 4070 printcy$;sp$(l+x1);ro$:ifzz=15thenzz=0:goto4090
  408. 4080 goto4120
  409. 4090 print:printwt$;we$:poke198,0:wait198,1
  410. 4100 ifpeek(203)=14thenx1=0:poke198,0:goto1830
  411. 4110 printcl$ye$"    [211]peise           [203]. [197]i. [198]t. [203]h. [193]rt     "
  412. 4120 next
  413. 4130 print:printwt$;we$:poke198,0:wait198,1
  414. 4140 ifpeek(203)=14thenx1=0:poke198,0:  goto1830
  415. 4150 poke198,0:goto1830
  416. 4160 rem **************************
  417. 4170 rem ****** stringzuweisungen *
  418. 4180 rem **************************
  419. 4190 cd$=chr$(017):cu$=chr$(145)
  420. 4200 ch$=chr$(029):ct$=chr$(157)
  421. 4210 rn$=chr$(018):rf$=chr$(146)
  422. 4220 ho$=chr$(019):cl$=chr$(147)
  423. 4230 rd$=chr$(028):gr$=chr$(030):de$=ct$+"  "+ct$+ct$
  424. 4240 cy$=chr$(159):ro$=chr$(031):ws$=chr$(5):bl$=chr$(175)
  425. 4250 kl$="          [203]alorienauswertung          "
  426. 4260 ks$=cl$+cd$+cd$+rd$+rn$+" "+kl$+" "+cd$
  427. 4270 f1$=cl$+rd$+rn$
  428. 4280 wt$=gr$+rn$+"            [215]eiter mit [211]pace            "
  429. 4290 we$=gr$+rn$+"               [197][206][196][197] = [[197]]               "
  430. 4300 s1$="        ":s2$="           "
  431. 4310 cp$=cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$
  432. 4320 fu$=cl$+ye$+rn$+cp$+s1$+"[211] [208] [197] [201] [195] [200] [197] [210]  [214] [207] [204] [204]"+s1$
  433. 4330 kd$=cl$+ye$+rn$+cp$+"[203]eine [196]atei unter diesem [206]amen vorhanden"
  434. 4340 c$(1)=ws$+bl$+ct$+cy$:c$(2)=rd$+bl$+ct$+cy$
  435. 4350 kv$=cl$+ye$+rn$+cp$+"        [203]eine [196]aten vorhanden!        "
  436. 4360 return
  437. 4370 rem **************************
  438. 4380 rem ************ ton-routine *
  439. 4390 rem **************************
  440. 4400 si=54272
  441. 4410 pokesi+24,15:pokesi+7,240:pokesi+8,10:pokesi+13,11
  442. 4420 pokesi+24,15:pokesi+0,111:pokesi+1,34:pokesi+6,13
  443. 4430 pokesi+11,17:pokesi+4,16
  444. 4440 pokesi+4,17:pokesi+4,16
  445. 4450 return
  446. 4460 rem **************************
  447. 4470 rem ************ get-routine *
  448. 4480 rem **************************
  449. 4490 printho$;:forxx=1tox:print:next:printspc(y):fori=1to150:next:return
  450. 4500 e$="":x=1
  451. 4510 printc$(x);:y=y+1:ify>10theny=1:x=x+1:ifx>2thenx=1
  452. 4520 gety$:ify$=""goto4510
  453. 4530 y=asc(y$):ify=13andlen(e$)>r-1thenprint"  ":return
  454. 4540 ify$=chr$(20)andlen(e$)>0thene$=left$(e$,len(e$)-1):printde$;:goto4520
  455. 4550 ifz=0thenify<32ory>127andy<160goto4520
  456. 4560 ifz=1thenify<32ory>32thenify<46ory>57goto4520
  457. 4570 iflen(e$)>l-1goto4510
  458. 4580 e$=e$+y$:printy$;:goto4510
  459. 4590 r=1:l=8:n=0:gosub4490
  460. 4600 poke198,0:poke53272,21:printcl$:end
  461. 4610 rem kalorientabelle ========64
  462. 4620 rem 38911 bytes memory    ====
  463. 4630 rem 14522 bytes program   ====
  464. 4640 rem 00266 bytes variables ====
  465. 4650 rem 03370 bytes arrays    ====
  466. 4660 rem 00657 bytes strings   ====
  467. 4670 rem 20096 bytes free (0)  ====
  468. 4680 rem ==========================
  469.